Turinys

# Operacijos „LibreOffice“ skaičiuoklėje

„LibreOffice“ skaičiuoklės operacijos:

## Aritmetiniai veiksmai

Šios operacijos grąžina skaitines reikšmes.

Operacija | Pavadinimas | Pavyzdys
--- | --- | ---
+ | Sudėtis | 1+1
- | Atimtis | 2-1
- | Inversija | -5
* | Daugyba | 2*2
/ | Dalyba | 9/3
% | Procentas | 15%
^ | Kėlimas laipsniu | 3^2

Prefix "-" (negation) has a higher precedence than "^" (exponentiation). For example -3^2 equals 9, which is the square of a negative number.

B^X may or may not report a #NUM! error when B is negative and X is not an integer. The expression =B^X is calculated the same way as =POWER(B;X).

## Palyginimo operacijos

Šių operacijų rezultatas yra tiesa arba netiesa.

Operacija | Pavadinimas | Pavyzdys
--- | --- | ---
= | Lygu | A1=B1
> | Daugiau | A1>B1
< | Mažiau | A1<B1
>= | Daugiau arba lygu | A1>=B1
<= | Mažiau arba lygu | A1<=B1
<> | Nelygu | A1<>B1

## Operacijos su tekstu

Operacija sujungia atskirus tekstinius fragmentus į vieną.

Operacija | Pavadinimas | Pavyzdys
--- | --- | ---
& | text concatenation | "pelė" & "žirnis" rezultatas yra "pelėžirnis"

## Operacijos su nuorodomis

Šios operacijos rezultatas yra nė vieno, vieno ar daugiau langelių sritis.

Aukščiausio pirmumo sritis, tuomet sankirta, galiausiai apjungimas.

Operacija | Pavadinimas | Pavyzdys
--- | --- | ---
: | Sritis | A1:C108, A:D or 3:13
! | Sankirta | SUM(A1:B6!B5:C12) Apskaičiuoja sankirtos langelių sumą; pavyzdyje rezultatas yra langelių B5 ir B6 turinių suma.

~

Susiejimas arba sujungimas

Takes two references and returns a reference list, which is a concatenation of the left reference followed by the right reference. Double entries are referenced twice.

=COUNT(A1:B2~B2:C3) counts values of A1:B2 and B2:C3. Note that the cell B2 is counted twice.

=INDEX(A1:B2~C1:D2;2;1;2) selects cell C2, that is, the first cell of the second row, first column, of the second range (C1:D2) of the range list.

A reference list is not allowed inside an array expression.

## Operator precedence

Associativity and precedence of operators, from highest to lowest precedence.

Associativity | Operator(s) | Comments
--- | --- | ---
left | : | Range.
left | ! | Reference intersection (A1:C4!B1:B5 is B1:B4).
left | ~ | Reference union.
right | +,- | Prefix unary operators. For example, -5 or -A1. Note that these have a different precedence than add and subtract.
left | % | Postfix unary operator % (divide by 100). Note that this is legal with expressions, for example, B1%.
left | ^ | Power (2^3 is 8).
left | *,/ | Multiply, divide.
left | +,- | Binary operations add, subtract. Note that unary (prefix) + and - have a different precedence.
left | & | Binary operation string concatenation. Note that "&" shall be escaped when included in an XML document.
left | =, <>, <, <=, >, >= | Comparison operators equal to, not equal to, less than, less than or equal to, greater than, greater than or equal to.

Prefix "-" has a higher precedence than "^", "^" is left-associative, and reference intersection has a higher precedence than reference union.

Prefix "+" and "-" are defined to be right-associative. However, note that typical applications which implement at most the operators defined in this specification (as specified) may implement them as left-associative, because the calculated results will be identical.

Precedence can be overridden by using parentheses, so "=2+3*4" computes to 14 but "=(2+3)*4" computes 20.

Susijusios temos

OpenDocument v1.3 part 4, Formula Operators

Paremkite mus!